Templates ignore section attributes so requires entries in linker script for IRAM code.

In the source code you'll see quite a bit of `__forceinline` as well as `IRAM_ATTR`, which is mainly for safety
and to indicate functions/methods may be used from interrupt context.

Unfortunately, marking templated code with `IRAM_ATTR` is not sufficient to get it into IRAM:

https://stackoverflow.com/questions/36279162/section-attribute-of-a-function-template-is-silently-ignored-in-gcc

So the linker script needs to be updated to catch all such instances. To do this requires splitting the `.text` output
segment into two parts, called `.text` and `.text1`. The rBoot script also needs to know about both segments
so they both end up in the ROM image it creates.

Using `CallbackTimer` as an example, most of the code gets inlined anyway and as it's called from task context
this actually uses very little IRAM.

More details here:

esp8266/Arduino#5922

Author: mikee47

Sming/Arch/Esp8266/Compiler/ld/common.ld

@@ -82,6 +82,55 @@ SECTIONS
     _data_end = ABSOLUTE(.);
   } >dram0_0_seg :dram0_0_phdr
 
+
+  /*
+  	IRAM is split into .text and .text1 to allow for moving specific
+  	functions into IRAM that would be matched by the irom0.text matcher
+  */
+  .text : ALIGN(4)
+  {
+    _stext = .;
+    _text_start = ABSOLUTE(.);
+     *(.UserEnter.text)
+    . = ALIGN(16);
+    *(.DebugExceptionVector.text)
+    . = ALIGN(16);
+    *(.NMIExceptionVector.text)
+    . = ALIGN(16);
+    *(.KernelExceptionVector.text)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    . = ALIGN(16);
+    *(.UserExceptionVector.text)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    . = ALIGN(16);
+    *(.DoubleExceptionVector.text)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    LONG(0)
+    . = ALIGN (16);
+    *(.entry.text)
+    *(.init.literal)
+    *(.init)
+
+    *(.iram.literal .iram.text.literal .iram.text .iram.text.*)
+
+	/*
+		GCC silently ignores section attributes on templated code.
+		The only practical workaround is enforcing sections in the linker script.
+	*/
+	*(.literal._ZN13CallbackTimer*)
+	*(.text._ZN13CallbackTimer*)
+    *(.text._ZNKSt8functionIF*EE*)  /* std::function<any(...)>::operator()() const */
+
+  } >iram1_0_seg :iram1_0_phdr
+
   .irom0.text : ALIGN(4)
   {
     _irom0_text_start = ABSOLUTE(.);
@@ -128,39 +177,12 @@ SECTIONS
     _flash_code_end = ABSOLUTE(.);
   } >irom0_0_seg :irom0_0_phdr
 
-  .text : ALIGN(4)
+
+  /* Pick up any remaining IRAM objects and close the text segment */
+  .text1 : ALIGN(4)
   {
-    _stext = .;
-    _text_start = ABSOLUTE(.);
-     *(.UserEnter.text)
-    . = ALIGN(16);
-    *(.DebugExceptionVector.text)
-    . = ALIGN(16);
-    *(.NMIExceptionVector.text)
-    . = ALIGN(16);
-    *(.KernelExceptionVector.text)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    . = ALIGN(16);
-    *(.UserExceptionVector.text)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    . = ALIGN(16);
-    *(.DoubleExceptionVector.text)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    LONG(0)
-    . = ALIGN (16);
-    *(.entry.text)
-    *(.init.literal)
-    *(.init)
     *(.literal .text .literal.* .text.* .stub .gnu.warning .gnu.linkonce.literal.* .gnu.linkonce.t.*.literal .gnu.linkonce.t.*)
-	  *(.iram.literal .iram.text.literal .iram.text .iram.text.*)
+
     *(.fini.literal)
     *(.fini)
     *(.gnu.version)

Sming/Components/rboot/component.mk

@@ -64,7 +64,7 @@ APP_CFLAGS				+= -DRBOOT_SPIFFS_1=$(RBOOT_SPIFFS_1)
 ROM_0_ADDR				:= 0x002000
 
 # filenames and options for generating rBoot rom images with esptool2
-RBOOT_E2_SECTS			?= .text .data .rodata
+RBOOT_E2_SECTS			?= .text .text1 .data .rodata
 RBOOT_E2_USER_ARGS		?= -quiet -bin -boot2
 
 RBOOT_ROM_0_BIN			:= $(FW_BASE)/$(RBOOT_ROM_0).bin