UART not able to wake ESP32 from Light Sleep

[dalbert2]

Hardware:

Board: ESP32 WROOM-32 on custom board
Core Installation version: 1.0.6
IDE name: VSCode with PlatformIO
Flash Frequency: 40Mhz
PSRAM enabled: no
Upload Speed: 115200
Computer OS: Windows 10

Description:

How can I wake the ESP32 from light sleep when a UART character is received?

Problem: system enters light sleep successfully, power consumption drops as expected, system wakes for timer, but UART activity does not trigger wake from sleep. Serial I/O works correctly when not entering light sleep mode.

Sketch:

#include <Arduino.h>
#include <driver/uart.h>

  // See: https://docs.espressif.com/projects/esp-idf/en/latest/esp32/api-reference/peripherals/uart.html#api-reference
  // See: https://docs.espressif.com/projects/esp-idf/en/latest/esp32c3/api-reference/system/sleep_modes.html#entering-light-sleep

void serialEvent();

void setup() {
  // wake from sleep every 10s
  esp_sleep_enable_timer_wakeup(10*1000000); 

  // Configure UART0
  Serial.begin(115200);
  while (!Serial) { delay(500); }
  uart_set_wakeup_threshold(UART_NUM_0, 3);   // 3 edges on U0RXD to wakeup
  esp_sleep_enable_uart_wakeup(UART_NUM_0);   // Enable UART 0 as wakeup source

  Serial.printf("ESP32 light sleep with UART wake\r\n");
  Serial.printf("SDK: %s\r\n", ESP.getSdkVersion());
  Serial.flush();

}

void loop() {
  if (Serial.available()) {
     Serial.printf("Got key: 0x%X\r\n", Serial.read());
     Serial.flush();
  } else {
     esp_light_sleep_start();
     esp_sleep_wakeup_cause_t wakeup_cause;
     wakeup_cause = esp_sleep_get_wakeup_cause();
     Serial.printf("Wake cause: %d\r\n",(int) wakeup_cause);
     Serial.flush();

  }
}

Debug Messages:

ets Jun  8 2016 00:22:57

rst:0x1 (POWERON_RESET),boot:0x13 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:2
load:0x3fff0018,len:4
load:0x3fff001c,len:1044
load:0x40078000,len:10124
load:0x40080400,len:5828
entry 0x400806a8
ESP32 light sleep with UART wake
SDK: v3.3.5-1-g85c43024c
Wake cause: 4
Wake cause: 4
etc.

[dalbert2]

Note that I am confident the hardware is working because if I configure GPIO3 as a GPIO input prior to light sleep, then I can use the gpio_wakeup to wake on each character received.

i.e. this does wake from sleep and displays wakeup cause 7 (ESP_SLEEP_WAKEUP_GPIO)

     // Reconfigure GPIO3  as GPIO instead of U0RXD and wake on low level
     PIN_FUNC_SELECT(PERIPHS_IO_MUX_U0RXD_U, FUNC_U0RXD_GPIO3);
     gpio_wakeup_enable(GPIO_NUM_3, GPIO_INTR_LOW_LEVEL);
     esp_sleep_enable_gpio_wakeup();
     // Enter light sleep mode
     esp_light_sleep_start();
     // Restore GPIO3 function as U0RXD
     PIN_FUNC_SELECT(PERIPHS_IO_MUX_U0RXD_U, FUNC_U0RXD_U0RXD);
     esp_sleep_wakeup_cause_t wakeup_cause;
     wakeup_cause = esp_sleep_get_wakeup_cause();
     Serial.printf("Wake cause: %d\r\n",(int) wakeup_cause);
     Serial.flush();

[stale]

[STALE_SET] This issue has been automatically marked as stale because it has not had recent activity. It will be closed in 14 days if no further activity occurs. Thank you for your contributions.

[stale]

[STALE_DEL] This stale issue has been automatically closed. Thank you for your contributions.

[stale]

[STALE_CLR] This issue has been removed from the stale queue. Please ensure activity to keep it openin the future.

[igrr]

This is indeed a bug. It occurs because light sleep wakeup requires UART pins to be connected via the IO MUX. HardwareSerial class (via UART HAL) always uses the GPIO matrix to configure the pins, even if the pins are the ones which can be connected via the IO MUX.
Same problem exists in ESP-IDF driver at the moment (internal reference IDF-3183), draft MR with a fix available, planned to be merged before IDF v4.4.
This might be easiest to fix when the issue is also fixed in IDF, and the HardwareSerial is ported to the IDF driver (#5403).

[SuGlider]

I confirm that the PR #5549 solves this issue, using ESP32.

Code used to test it:

#include <esp_sleep.h>
#include <driver/uart.h>

#define LED  2

void setup() {
  Serial2.begin(115200);
  pinMode(LED, OUTPUT);

  while (!Serial2) {
    delay(500);
  }

  // uses UART_2 for sending messages to user
  Serial2.println();
  Serial2.println("LIGHT SLEEP ENABLED - type something to wake it up!");

  // makes sure the message goes out before entering in Light Sleep
  Serial2.flush();

  int wake_thresh = 3;
  uart_set_wakeup_threshold(UART_NUM_0, wake_thresh);
  esp_sleep_enable_uart_wakeup(UART_NUM_0);

  esp_light_sleep_start();

  // ESP32 is now in light sleep mode 
  // Send something on UART_0 to wake it up

  // Starts UART_0 now
  Serial.begin(115200);
  while (!Serial) {
    delay(500);
  }
  
  // Clean Serial from wake up message
  Serial.flush();
  Serial.readString();

  // uses UART_2 for sending messages to user
  Serial2.println();
  Serial2.println("LIGHT SLEEP WAKE UP");
  Serial2.end();

  Serial.println();
  Serial.println("Hey, I' back! Send messages to UART_0 to see echo back...");
  Serial.println();
}

void loop() {
  // This function will only run when ESP32 returns from Light Sleep!
  digitalWrite(LED, HIGH);
  delay(50);
  digitalWrite(LED, LOW);
  delay(50);

  while (Serial.available() > 0) {
    Serial.write(Serial.read());
  }
}

[SuGlider]

Actually, I tested the scketch above using version 1.0.6 and 2.0.0.
It works on both. ESP32 goes sleep and then wakes up when something is sent to UART0.